New Members: Be sure to confirm your email address by clicking on the link that was sent to your email inbox. You will not be able to post messages until you click that link.

Weird results in the scan

Althought I have clearly set the parameters but the scan still returns me ETFs and Indexes and weird enough results from other world market and OTC market as well. Any idea what could be going wrong here?


// set stock universe
[Country is US]

and

[type = stock] AND [group is not ETF] and [name not contains "Trust"] and [name not contains "Notes Due"] and [name not contains "Shares"] and [name not contains "Fund"]

and [exchange is NYSE]

and [exchange is NASDAQ]

and [SCTR >75]

and [today's ema(3,close) > today's ema(5,close)] and [today's ema(5,close) > today's ema(8,close)] and [today's ema(8,close) > today's ema(10,close)] and [today's ema(10,close) > today's ema(12,close)] and [today's ema(12,close) > today's ema(15,close)]

and [today's ema(15,close) > today's ema(30,close)] and [yesterday's ema(15,close) <= yesterday's ema(30,close)]
or [today's ema(15,close) > today's ema(35,close)] and [yesterday's ema(15,close) <= yesterday's ema(35,close)]
or [today's ema(15,close) > today's ema(40,close)] and [yesterday's ema(15,close) <= yesterday's ema(40,close)]
or [today's ema(15,close) > today's ema(45,close)] and [yesterday's ema(15,close) <= yesterday's ema(45,close)]
or [today's ema(15,close) > today's ema(50,close)] and [yesterday's ema(15,close) <= yesterday's ema(50,close)]
or [today's ema(15,close) > today's ema(60,close)] and [yesterday's ema(15,close) <= yesterday's ema(60,close)]


Comments

  • markdmarkd mod
    edited January 2018
    2 problems I can see.

    1. You are asking for stocks that trade on both the NYSE and NASDAQ. There are no stocks that fit that condition.

    2. The bigger problem is, you need to isolate your "or" statements. You have to put brackets around the alternative conditions to group them separate them from the necessary conditions.

    Without brackets, a symbol only has to match ONE condition in the entire scan, and the scan engine will return it.

    With brackets, a symbol has to match at least one condition within the brackets, AND all the other conditions.

    I've added an "or" statement for the exchanges. Also, I added a pair of brackets around your "or" statements to group them. I don't know if I grouped them as you want them.


    // set stock universe
    [Country is US]
    and
    [
    [exchange is NYSE]
    or
    [exchange is NASDAQ]
    ]
    and [type = stock]
    and [group is not ETF]
    and [name not contains "Trust"]
    and [name not contains "Notes Due"]
    and [name not contains "Shares"]
    and [name not contains "Fund"]


    and [SCTR >75]

    and [today's ema(3,close) > today's ema(5,close)] and [today's ema(5,close) > today's ema(8,close)] and [today's ema(8,close) > today's ema(10,close)] and [today's ema(10,close) > today's ema(12,close)] and [today's ema(12,close) > today's ema(15,close)]

    and
    [
    [today's ema(15,close) > today's ema(30,close)] and [yesterday's ema(15,close) <= yesterday's ema(30,close)]
    or [today's ema(15,close) > today's ema(35,close)] and [yesterday's ema(15,close) <= yesterday's ema(35,close)]
    or [today's ema(15,close) > today's ema(40,close)] and [yesterday's ema(15,close) <= yesterday's ema(40,close)]
    or [today's ema(15,close) > today's ema(45,close)] and [yesterday's ema(15,close) <= yesterday's ema(45,close)]
    or [today's ema(15,close) > today's ema(50,close)] and [yesterday's ema(15,close) <= yesterday's ema(50,close)]
    or [today's ema(15,close) > today's ema(60,close)] and [yesterday's ema(15,close) <= yesterday's ema(60,close)]
    ]
  • Many many thanks as usual @markd . You're the best
Sign In or Register to comment.