Favorite Scan

Comments

• Options

  lmkwin ✭✭

  January 2021 edited January 2021

  Here's one I stole from markd. I call it Darvas Box markd. @markd posting from 2015 below.
  
  Darvas had a fundamental filter, not just technical ones, including that stocks should be newer companies in emerging and/or leading industries. The method suggested in the pdf to screen on other sites for fundamentals sounds helpful. This scan doesn't pick up fundamentals - you would add your own groups from the Sectors and Industries list (or use an "or" statement with a list of symbols you found on the fundamental sites). Also, the 5 and 10 per cent parameters in this scan are arbitrary. So, this scan isn't definitive, but it pulls up some good charts, at least some of which ought to look like Darvas stocks:
  
  [type = stock]
  
  // leading industries (you fill this in)
  
  // and [[group is ?] or [group is ?] or [etc...]]
  
  // market leading technical strength
  
  and [SCTR > 90]
  
  // in an uptrend (just in case the SCTR rank is strength in a bear market)
  // 200 and 50 MAs rising and 50 above 200
  
  and [sma(200,close) > 20 days ago sma(200, close)]
  and [sma(50, close) > 10 days ago sma(50, close)]
  and [sma(50,close) > sma(200,close)]
  
  
  // made new yearly high in the last month or less
  
  and [Upper Price Chan(21) = Upper Price Chan(251)]
  
  // recent decline greater than 5 per cent of recent best high
  
  and [min(15, low) < max(21, high)*.95]
  
  // recent decline less than 10 per cent from best high
  
  and [min(15,low) > max(21,high) *.9]
  
  Note, this scan picks up possible set ups, not signals. The Darvas signal would be a close above Upper Price Chan(251). Darvas also required that the cross to new highs be accomplished on strong volume, so keep that in mind.

  0
• Options

  markd mod

  January 2021 edited January 2021

  Somebody said, plagiarism is the sincerest form of flattery. Might be true.
  
  Here's one dusted off from the archives. It's a breakout scan. It may not be as good as it once was. But run it from a number of Friday dates ( you can experiment with other days, too) over the past few months to get a feel for how it's working now (if it is). Not just recently, because the market has been up - but back in February - March while things were going down.
  
  It picks up junk as well as gems, and the point is to find candidates to check out - hits are NOT entries. You would be looking for a longer term position to ride, or something to swing trade on the way up. So, you do not necessarily have to get in right away. Remember to set the chart to end on the scan date to see how the chart looked on the scan date. It could help you see the difference between the gems and the junk.
  
  When you look at the chart, the stock's RS (or SCTR) should be off the bottom and improving but the SCTR might not actually be good yet because SCTR has a long term element.
  
  You probably want to see some evidence of persistent buying on the chart (some recent time above a rising mid length MA before the hit, or rising mid length channel (mid length to me is 63 days or 13 weeks or so), not just a sudden pop.
  
  So give your self a chart style that shows these things.
  
  A good example chart from scan date December 1 2020 was MOGO. Also, STON. No idea how they will do from here, but they have done well since shortly after the hit date. (I ran the scan tonight 1/14, not 12/1 - I'm not in these, don't know anything about them). Not so good, at least so far, was CAAS. If the rise is too steep, it could be short covering and not real buying.
  
  If the chart is interesting, its generally worthwhile to look up hits on finviz to check the news flow, then go deeper if its promising.
  
  Whether the hits keep coming depends on the market. Sometimes it rains, sometimes there's nothing.
  
  Obviously, you can edit the universe for what interests you.
  
  // 20 00 10 01 Long term K251 breakout
  
  // weekly scan - set calendar to a previous Friday
  
  // Find likely first weekly close above UPC in at least 3 years
  // suggests radical change in sentiment
  
  
  [[exchange is NYSE] or [exchange is NASD]]
  
  and [type is stock]
  
  and [group is not ETF]
  
  // PRICE
  
  // close
  and [close > 1]
  
  // VOLUME
  
  and [market cap > 100]
  and [sma(63, volume) > 100000]
  
  // as of last week's close, weekly close has not been above K 99 for three years
  and [1 week ago weekly max(156, weekly Fast Stoch %K(52,1)) < 90]
  
  // last week's UPC 52 is lowest in three years
  and [1 week ago weekly Upper Price Chan(52) = 1 week ago weekly min(156, weekly Upper Price Chan(52))]
  
  // this week's close breaks last week's 52 week high
  and [weekly close > 1 week ago weekly Upper Price Chan(52)]

  0
• Options

  Inv334 ✭

  January 2021

  Momentum Investing. The formulas are derived from Brian Livingstone's Muscular Porfolios. He had a blog called Muscular Investing in late 2018 and most of 2019. He has a procedure. Here is a link.
  
  The Mama Bear Portfolio | Muscular Portfolios updates every 10 minutes
  5 months
  Rank by [daily roc(105)]
  
  Yearly, 6 months, quarter
  Rank by [daily roc (252) + daily roc (127) + daily roc (63)]
  
  Fundx : (This scan is really close to their monthly ETF report)
  Livingstone's TSP uses this formula, I think.
  Rank by [daily roc (252) + daily roc (127) + daily roc (63) + daily roc (21) + daily roc (5)]
  
  6 months
  Rank by [daily roc(127) + daily roc(63) + daily roc(21) + daily roc(5)]
  
  ##MONTHLY RANKS FOR A YEAR
  Rank by [monthly roc(6) + monthly roc(12)]
  
  

  0
• Options

  Inv334 ✭

  January 2021

  https://muscularportfolios.com Here is the site.

  0